99 lines
4.3 KiB
Kotlin
99 lines
4.3 KiB
Kotlin
/* ------------------------------ Plugins ------------------------------ */
|
|
plugins {
|
|
id("java") // Import Java plugin.
|
|
id("java-library") // Import Java Library plugin.
|
|
id("com.diffplug.spotless") version "8.1.0" // Import Spotless plugin.
|
|
id("checkstyle") // Import Checkstyle plugin.
|
|
eclipse // Import Eclipse plugin.
|
|
}
|
|
|
|
/* --------------------------- JDK ------------------------------------- */
|
|
java {
|
|
sourceCompatibility = JavaVersion.VERSION_17 // Compile with JDK 17 compatibility.
|
|
toolchain { // Select Java toolchain.
|
|
languageVersion.set(JavaLanguageVersion.of(17)) // Use JDK 17.
|
|
vendor.set(JvmVendorSpec.GRAAL_VM) // Use GraalVM CE.
|
|
}
|
|
}
|
|
|
|
/* ----------------------------- Metadata ------------------------------ */
|
|
group = "com.extendedclip.papi.expansion.player" // Declare bundle identifier.
|
|
|
|
version = "2.0.9" // Declare expansion version (will be in .jar).
|
|
|
|
/* ---------------------------- Repos ---------------------------------- */
|
|
repositories {
|
|
mavenCentral() // Import the Maven Central Maven Repository.
|
|
gradlePluginPortal() // Import the Gradle Plugin Portal Maven Repository.
|
|
maven { url = uri("https://repo.purpurmc.org/snapshots") } // Import the PurpurMC Maven Repository.
|
|
maven { url = uri("https://repo.extendedclip.com/releases") } // Import the PlaceholderAPI Maven Repository.
|
|
maven { url = uri("file://${System.getProperty("user.home")}/.m2/repository") }
|
|
System.getProperty("SELF_MAVEN_LOCAL_REPO")?.let { // TrueOG Bootstrap mavenLocal().
|
|
val dir = file(it)
|
|
if (dir.isDirectory) {
|
|
println("Using SELF_MAVEN_LOCAL_REPO at: $it")
|
|
maven { url = uri("file://${dir.absolutePath}") }
|
|
} else {
|
|
logger.error("TrueOG Bootstrap not found, defaulting to ~/.m2 for mavenLocal()")
|
|
mavenLocal()
|
|
}
|
|
} ?: logger.error("TrueOG Bootstrap not found, defaulting to ~/.m2 for mavenLocal()")
|
|
}
|
|
|
|
/* ---------------------- Java project deps ---------------------------- */
|
|
dependencies {
|
|
compileOnly("org.purpurmc.purpur:purpur-api:1.19.4-R0.1-SNAPSHOT") // Purpur API (compile-time only).
|
|
compileOnly("me.clip:placeholderapi:2.11.6") // PlaceholderAPI (compile-time only).
|
|
}
|
|
|
|
/* ---------------------- Reproducible jars ---------------------------- */
|
|
tasks.withType<AbstractArchiveTask>().configureEach { // Ensure reproducible .jars
|
|
isPreserveFileTimestamps = false
|
|
isReproducibleFileOrder = true
|
|
}
|
|
|
|
/* ----------------------------- Jar ----------------------------------- */
|
|
tasks.jar {
|
|
archiveBaseName.set("Player-PAPI") // Final artifact name: Player-PAPI-<version>.jar.
|
|
archiveClassifier.set("")
|
|
manifest { attributes(mapOf("Implementation-Title" to project.name, "Implementation-Version" to project.version)) }
|
|
}
|
|
|
|
tasks.build { dependsOn(tasks.spotlessApply) } // Build depends on spotless.
|
|
|
|
/* --------------------------- Javac opts ------------------------------- */
|
|
tasks.withType<JavaCompile>().configureEach {
|
|
options.compilerArgs.add("-parameters") // Enable reflection for java code.
|
|
options.isFork = true // Run javac in its own process.
|
|
options.compilerArgs.add("-Xlint:deprecation") // Trigger deprecation warning messages.
|
|
options.encoding = "UTF-8" // Use UTF-8 file encoding.
|
|
}
|
|
|
|
/* ----------------------------- Auto Formatting ------------------------ */
|
|
spotless {
|
|
java {
|
|
eclipse().configFile("config/formatter/eclipse-java-formatter.xml") // Eclipse java formatting.
|
|
leadingTabsToSpaces() // Convert leftover leading tabs to spaces.
|
|
removeUnusedImports() // Remove imports that aren't being called.
|
|
}
|
|
kotlinGradle {
|
|
ktfmt().kotlinlangStyle().configure { it.setMaxWidth(120) } // JetBrains Kotlin formatting.
|
|
target("build.gradle.kts", "settings.gradle.kts") // Gradle files to format.
|
|
}
|
|
}
|
|
|
|
checkstyle {
|
|
toolVersion = "10.18.1" // Declare checkstyle version to use.
|
|
configFile = file("config/checkstyle/checkstyle.xml") // Point checkstyle to config file.
|
|
isIgnoreFailures = true // Don't fail the build if checkstyle does not pass.
|
|
isShowViolations = true // Show the violations in any IDE with the checkstyle plugin.
|
|
}
|
|
|
|
tasks.named("compileJava") {
|
|
dependsOn("spotlessApply") // Run spotless before compiling with the JDK.
|
|
}
|
|
|
|
tasks.named("spotlessCheck") {
|
|
dependsOn("spotlessApply") // Run spotless before checking if spotless ran.
|
|
}
|